Generating and opening file with Automator

This isn't too difficult to do, you just need to know the right magic. I'll walk you through it.

1. Open Automator, and when prompted to choose a type for your document, select Service. If you're not prompted, just hit ⌘N to make a new automator file.
2. At the top of the rightmost panel, make sure that Output replaces selected text is checked, and the first drop-down is set to text:
   • You can change the any application part to a specific application if you only want it to work in that program.
3. In the Actions Library in the left panel, find Run Shell Script and double click it to add it to the workflow.
4. Change the Shell drop down to /usr/bin/python, and make sure that Pass input is set to stdin.
5. Delete the existing text in the script box, and replace it with the code below.
6. Save it with a descriptive name. Automator will save it in the ~/Library/Services/ folder.
7. Optional: Go to Keyboard Preferences, and find your service in the Services section of the Keyboard Shortcuts tab. You can assign a system-wide shortcut for it there.

Script Code

import sys

for f in sys.stdin:
    print f.replace('-', ' ').replace('%', ' ').replace('&', ' and ').replace('#', ' ').title(),

I've tried with Automator without succeeding looping through dropped files.

Here's a folder action script that does what you want, and how to attach it to a folder :

1. Open AppleScript Editor

2. Paste the following script into a new document

property mail_subject : "An image for you"
property mail_plain_content : "Attached you will the image you required." & return & return & "Best Regards" & return & "Automator"
property mail_html_content : "Attached you will the image you required.<br><br>Best Regards<br>Automator"

on adding folder items to this_folder after receiving these_items
    processItems(these_items)
end adding folder items to

on processItems(these_items)
    repeat with i from 1 to (count of these_items)
        set this_item to item i of these_items
        if isFolder(this_item) then
            processItems(getFolderItems(this_item))
        else
            processFile(this_item)
        end if
    end repeat
end processItems

on processFile(this_file)
    set mail_address to RemoveExtension(getFileName(this_file))
    tell application "Microsoft Outlook"
        set newMessage to make new outgoing message with properties {subject:mail_subject, plain text content:mail_plain_content, content:mail_html_content}
        tell newMessage
            make new recipient with properties {email address:{address:mail_address}}
            make new attachment with properties {file:this_file as alias}
            send
        end tell
        activate
    end tell
end processFile

on isFolder(this_item)
    tell application "System Events" to return (exists folder (this_item as string))
end isFolder

on RemoveExtension(this_name)
    -- This function comes from :
    -- http://www.macosxautomation.com/applescript/sbrt/index.html
    if this_name contains "." then
        set this_name to (the reverse of every character of this_name) as string
        set dot_offset to the offset of "." in this_name
        set this_name to (text (dot_offset + 1) thru -1 of this_name)
        set this_name to (the reverse of every character of this_name) as string
    end if
    return this_name
end RemoveExtension

on getExtension(this_name)
    if this_name contains "." then
        set this_name to (the reverse of every character of this_name) as string
        set dot_offset to the offset of "." in this_name
        set this_name to (text 1 thru (dot_offset - 1) of this_name)
        set this_name to (the reverse of every character of this_name) as string
        return this_name
    else
        return ""
    end if
end getExtension

on getFileName(this_file)
    tell application "Finder" to return name of this_file
end getFileName

on getFolderItems(this_folder)
    tell application "Finder" to return items of this_folder
end getFolderItems

3. Save it in your ~/Library/Scripts/Folder Action Scripts Folder

Menu File > Save

Go to the right folder : press cmd+G and paste:
~/Library/Scripts/Folder Action Scripts
and click Go

Save as : Image - Email using name as address.scpt (for example)
Format : Script

4. Create a new folder that will be watched for added items

5. Associate the script to the folder

In the Finder, right click on your folder, then select Services > Folder Actions Setup Select the new created Image - Email using name as address.scpt script

You're done, drop a file whose name is an address, mail will be sent.