Applescript – Fixing Blank Shell Output to Variable

applescriptcommand line

Hi I'm trying to get the cpuValue but I get "" for the variable.

set cpuValue to ""
getProcessPercentCPU("Safari")

on getProcessPercentCPU(someProcess)
    set cpuValue to do shell script "/bin/ps -xco %cpu,command | /usr/bin/awk '/" & someProcess & "$/ {print $1}'"
end getProcessPercentCPU

log "output:" & cpuValue

Output

""

Best Answer

AppleScript treats variables created with set as local by default (although the documentation isn't totally clear IMO). This means that the cpuValue variable inside on getProcessPercentCPU is local to that handler, and different from the variable with the same name in the outer scope.

Essentially, you have two different variables that just happen to have the same name, one set to "", the other to the CPU percentage for the Safari process.

You could solve this by adding global cpuValue inside the handler, but returning values in global variables isn't good programming practice. It's almost always better to return values like a function:

set cpuValue to getProcessPercentCPU("Safari")
    
on getProcessPercentCPU(someProcess)
    set processPercentCPU to do shell script "/bin/ps -xco %cpu,command | /usr/bin/awk '/" & someProcess & "$/ {print $1}'"
    return processPercentCPU
end getProcessPercentCPU
    
log "output:" & cpuValue

Related Solutions

String and Variable concatenation not working in Applescript

If you run

set user to "johndoe"
set source to POSIX file "/Users/" & user & "/Documents"

the result is

{file "Macintosh HD:Users:", "johndoe", "/Documents"}

Just put parentheses around the path:

set user to "johndoe"
set source to POSIX file ("/Users/" & user & "/Documents")

MacOS – Difference between variable and pipe to shell in applescript

There is a hidden error that is generated when you run your "working" script... You have to bump the shell script part of the code into its own tell current application block as shown in the second example below...

This version works for me with creating a TextEdit document:

global presenterNotes
tell application "Keynote"
    activate
    -- open (choose file)
    tell front document
        set presenterNotes to presenter notes of every slide as text
        set the clipboard to presenterNotes
    end tell
    tell application "TextEdit"
        activate
        make new document with properties {name:"KeynoteNotes.txt"}
        set text of front document to presenterNotes
    end tell
end tell

The shell pbpaste version with proper blocking to avoid error -10004:

global presenterNotes
tell application "Keynote"
    activate
    -- open (choose file)
    tell front document
        set presenterNotes to presenter notes of every slide as text
        set the clipboard to presenterNotes
    end tell
    tell current application
        do shell script "pbpaste > ~/keynote-notes1.txt"
    end tell
end tell

Best Answer

Related Solutions

String and Variable concatenation not working in Applescript

MacOS – Difference between variable and pipe to shell in applescript

Related Question