Sorting an array based on substring of each element

arrayzsh

How does one sort an array based on a substring of each element ?
e.g. given an array like

arr=( 2some05stuff 4more02stuff 3evenmore01stuff 1no04stuff )

I'd like to sort the elements by the numerical string that precedes stuff so I end up with

3evenmore01stuff
4more02stuff
1no04stuff
2some05stuff

I know that parameter expansion flags o/O reorder an array e.g.

print -rl "${(@on)arr}"

1no04stuff
2some05stuff
3evenmore01stuff
4more02stuff

and

print -rl "${(@On)arr}"

4more02stuff
3evenmore01stuff
2some05stuff
1no04stuff

I just don't know if it's possible to combine them flags with a function or other parameter expansion like e.g. subscript removal or subscript expansion…

Best Answer

I don't know of a way to do this inline. With globs qualifiers, you can specify a sort key (*(oe\''REPLY=${${REPLY%stuff*}##*[^0-9]}'\')), but there's no such thing with parameter expansion modifiers.

What you can do is build an auxiliary array containing ${sort_key}$'\0'${value}, i.e. append a null byte and the original value to the sort key. Assuming that the sort keys don't contain null bytes, sorting that array gives the desired order, and stripping off the sort key prefix gives the desired result.

typeset -a tmp; tmp=(); typeset -i i
for ((i=1; i<=$#arr; i++)); do tmp[$i]=${${arr[$i]%stuff*}##*[^0-9]}$'\0'$arr[$i]; done
print -lr "${(@)${(@o)tmp}#*$'\0'}"

Related Solutions

Apply parameter expansion flags to string or array literal in zsh

I think you are looking for :- parameter substitution:

$ restofarglist='abc,def'
$ echo ${(s/,/)${:-arg1,arg2,$restofarglist}}
arg1 arg2 abc def

From man zsh:

${name:-word}
              If name is set, or in the second form is non-null, then substitute its value;
              otherwise substitute word.  In the second form name may be omitted, in  which
              case word is always substituted.

Actually you can make this example a little bit shorter:

$ echo ${${:-arg1,arg2,$restofarglist}//,/ }
arg1 arg2 abc def

Append (alter) each array element via parameter expansion (i.e. without printf)

Use $^array.

It turns the array into a sort of brace expansion of the array. As in when a=(foo bar baz), $^a would be a bit like {foo,bar,baz}.

$ a=(foo bar baz)
$ echo prefix${^a}suffix
prefixfoosuffix prefixbarsuffix prefixbazsuffix

For multiplexing arrays:

$ a=(1 2 3) b=(a b c)
$ echo $^a$^b
1a 1b 1c 2a 2b 2c 3a 3b 3c

Naturally, if the prefix or suffix contain shell special characters (like ; that separates commands or space that separate words, or $"'&*[?~...), they must be quoted:

echo 'p r e f i x '$^a' s u f f i x'

same as for csh's (and bash, ksh, zsh's):

echo 'p r e f i x '{foo,bar,baz}' s u f f i x'

$^a itself must not be quoted, "foo${^a}bar" would expand as one word. One case where you would want $^array to be quoted, the same as for $array is when you want to preserve empty elements. Then, you need to quote the array expansion and use the (@) flag or the "${array[@]}" syntax (reminiscent of the Bourne shell's "$@"):

$ array=(x '')
$ printf '<%s>\n' $array         # empties removed
<x>
$ printf '<%s>\n' "$array"       # array elts joined with spaces
<x >
$ printf '<%s>\n' "${(@)array}"  # empties preserved
<x>
<>
$ printf '<%s>\n' "$array[@]"    # empties preserved
<x>
<>
$ printf '<%s>\n' $^array$^array # empty removed
<xx>
<x>
<x>
$ printf '<%s>\n' "$^array$^array" # concatenation of joined arrays
<x x >
$ printf '<%s>\n' "$^array[@]$^array[@]" # multiplexing with empties preserved
<xx>
<x>
<x>
<>

Best Answer

Related Solutions

Apply parameter expansion flags to string or array literal in zsh

Append (alter) each array element via parameter expansion (i.e. without printf)

Related Question