The canonical tool for that would be sed.

sed -n -e 's/^.*stalled: //p'

Detailed explanation:

• -n means not to print anything by default.
• -e is followed by a sed command.
• s is the pattern replacement command.
• The regular expression ^.*stalled: matches the pattern you're looking for, plus any preceding text (.* meaning any text, with an initial ^ to say that the match begins at the beginning of the line). Note that if stalled: occurs several times on the line, this will match the last occurrence.
• The match, i.e. everything on the line up to stalled:, is replaced by the empty string (i.e. deleted).
• The final p means to print the transformed line.

If you want to retain the matching portion, use a backreference: \1 in the replacement part designates what is inside a group \(…\) in the pattern. Here, you could write stalled: again in the replacement part; this feature is useful when the pattern you're looking for is more general than a simple string.

sed -n -e 's/^.*\(stalled: \)/\1/p'

Sometimes you'll want to remove the portion of the line after the match. You can include it in the match by including .*$ at the end of the pattern (any text .* followed by the end of the line $). Unless you put that part in a group that you reference in the replacement text, the end of the line will not be in the output.

As a further illustration of groups and backreferences, this command swaps the part before the match and the part after the match.

sed -n -e 's/^\(.*\)\(stalled: \)\(.*\)$/\3\2\1/p'

GNU sed way

In GNU sed (if you are using some Linux distribution it should be default sed implementation), you can use something like this:

sed '/.production =/,+12d' inputfile.txt

How it works:

1. It scans the input file line by line (this is how sed works) and check if the command should be used.
2. Our command is d (the last character) which means delete the line.
3. But this command will only run if current line does match our range.
4. The range is specified by two arguments (start and end of range, inclusive) delimited by , character. First is a regular expression /.production =/ which match each line containing this expression. Second argument is +12d which means 12 lines from start range.
5. So our range matches each line that matches expression and next 12 lines and deletes them.
6. All the other lines are printed to the output (default sed behaviour).

Portable, ugly way

This one should work on other sed implementation but involves much more typing and is not so robust:

sed '/.production =/{N;N;N;N;N;N;N;N;N;N;N;N;d}' somefile.txt

How it works:

1. It scans the input file line by line (this is how sed works) and check if the command should be used.
2. It checks if the line matches the /.production =/ pattern. If so, it runs all the commands in {} braces.
3. We run N comamnd 12 times. N command reads next line and appends it to current buffer. So after we run it 12 times, we have 13 lines concatenated in current buffer (first line + 12 read by N commands).
4. Now we run d command which deletes this concatenated 13 lines.
5. sed continues until it finds another pattern and again deletes 13 lines. All the other lines are printed (default sed behaviour).