sed on OSX – How to Insert at a Certain Line

gnuosxposixsed

So I've been using 'sed' on linux for a while, but have had a bit of difficulty trying to use it on OSX since 'POSIX sed' and 'GNU sed' have so many little differences. Currently I'm struggling with how to insert a line of text after a certain line number. (in this case, line 4)

On linux I would do something like this:

sed --in-place "4 a\  mode '0755'" file.txt

So on OSX I tried this:

sed -i "" "4 a\ mode '0755'" file.txt

However this keeps giving me a 'extra characters after \ at the end of a command' error. Any ideas what's wrong here? Do I have a typo? Or am I not understanding another difference between versions of sed?

Best Answer

Strictly speaking, the POSIX specification for sed requires a newline after a\:

[1addr]a\
text
Write text to standard output as described previously.

This makes writing one-liners a bit of a pain, which is probably the reason for the following GNU extension to the a, i, and c commands:

As a GNU extension, if between the a and the newline there is other than a whitespace-\ sequence, then the text of this line, starting at the first non-whitespace character after the a, is taken as the first line of the text block. (This enables a simplification in scripting a one-line add.) This extension also works with the i and c commands.

Thus, to be portable with your sed syntax, you will need to include a newline after the a\ somehow. The easiest way is to just insert a quoted newline:

$ sed -e 'a\
> text'

(where $ and > are shell prompts). If you find that a pain, bash [1] has the $' ' quoting syntax for inserting C-style escapes, so just use

sed -e 'a\'$'\n''text'

[1] and mksh (r39b+) and some non-bash bourne shells (e.g., /bin/sh in FreeBSD 9+)

Related Solutions

Sed command that would ignore any commented match

You should not believe them if they tell you it cannot be done. You should believe them, however, if they tell you it's not easy.

sed '\|*/|!{ s|/\*|\n&|              #if ! */ repl 1st /* w/ \n/*
     h;      s|foo|bar|g;/\n/!b      #hold; repl all foo/bar; if ! \n branch
     G;      s|\n.*\n||;:n           #Get; clear difference; :new label
     n;      \|*/|!bn;s|^|\n/*|      #new line; if ! */ branch new label
     };s|*/|\n&|g                    #repl all */ w/ \n*/
       s|foo|&\nbar|g;:r             #repl all foo w/ foo\nbar
       s|\(/\*[^\n]*\)\nbar|\1|g;tr  #repl all /*[^\n]*\nbar w/ foo
       s|foo\n\(b\)|\1|g             #repl all foo\nbar w/ bar
       s|^\n/.||;s|\n||g             #clear any \n inserts
'    <<\INPUT
asfoo   /* asdfooasdfoo


asdfasdfoo
asdfasdfoo
foo */foo /*foo*/ foo
/*.
foo*/
foo
hello

INPUT

OUTPUT

asbar   /* asdfooasdfoo


asdfasdfoo
asdfasdfoo
foo */bar /*foo*/ bar
/*.
foo*/
bar
hello

Shell – sed insert in the beginning of multiple files is not working

To edit file in-place with OSX sed, you need to set empty extension:

$ sed -i '' '1i\
#encoding:utf-8' filename

And you need a literal newline after i\. This is specified by POSIX sed.

Only GNU sed allows text to be inserted on the same line with command.

sed can also works with multiple files at once, so you can use -exec command {} + form:

$ find . -iname "*.erb" -type f -exec sed -i '' '1i\
#encoding:utf-8' {} +

Best Answer

Related Solutions

Sed command that would ignore any commented match

OUTPUT

Shell – sed insert in the beginning of multiple files is not working

Related Question