Replace all letters in a word with ‘*’ after a certain word in a text file

sedtext processing

I need to create a script that replaces all letters of a word after a certain word with an asterisk (*).
For example:

sed 's/Word:[^ ]\+/Word:*/' Desktop/script_test

But this script replaces the entire word with only one asterisk, while I want to replace all letters. How can I do that?
For example, with this input:

Word: cat

I want to get

Word: ***

I am running Linux.

P.S. The input must be read from a text file and also saved to the same file.

Best Answer

You could do it one at a time in a loop:

sed -e :1 -e 's/\(Word: *[^ ]*\)[^ *]/\1*/;t1'

To edit the file in place and assuming all the characters to replace are single-byte, you can make both sed's stdin and stdout the file as in:

sed ... < file 1<> file

Or with GNU sed, use the -i flag as in:

sed -i ... file

(Though that will replace the file with a new one (though with the same name). With BSD sed, use -i '' instead of -i).

Related Solutions

Sed one-liner to replace word-medial capitals

A capital W doesn't occur at the end of a word either, but it may occur in an all-caps abbreviation. So I'd replace W when it's immediately after a lowercase letter, or when it follows an uppercase letter and precedes a lowercase letter (aWre).

sed -e 's/\([[:lower:]]\)W/\1fi/g' -e 's/\([[:alpha:]]\)W\([[:lower:]]\)/\1fi\2/g'

This doesn't cover fifi (which my biggest word list only finds it in “fifing”). More importantly, this doesn't cover W at the beginning of a word; you can capture some cases by looking at the second letter, but that's still going to miss many words that begin with fi. In English, many letters never appear after a W:

… -e 's/\([^[:alnum:]]\)W\([b-dfgj-npqstv-xz]\)/\1fi\2/g' \
  -e 's/^W\([b-dfgj-npqstv-xz]\)/fi\2/'

For more precise results and to cope with other languages, you can switch to a more complex dictionary-based approach (which fancy OCR systems often use, evidently yours isn't fancy enough).

Bash – Strip spaces after single capital letters with sed

This takes care of names like A B Chadwick and A B C D'Souza

Text such as A B cde and A B CDE are not modified.

It uses two temporary null characters \x00 to mark changes (per name) as it progress through a line, removing spaces.

:N and :S are branch-to labels (any name will do)
t and b are branching instructions.
t branches upon a successful replacemnt in the previous s/../../ command.
b branches unconditionally.

sed -r ":N                                                # loop per name
         /(\<[A-Z]\> )+[A-Z][a-z']/{                      # line needs action
             s/((\<[A-Z]\> )+)([A-Z][a-z'])/\x00\1\x00\3/ # add \x00 markers
            :S                                            # loop per space
             s/(\x00[A-Z]+) (\<[A-Z]\>)/\1\2/             # delete a space
             t S                                          # any more spaces? 
             b N                                          # any more names?
         }; s/\x00//g"                                    # remove \x00

Best Answer

Related Solutions

Sed one-liner to replace word-medial capitals

Bash – Strip spaces after single capital letters with sed

Related Question