Insert newline before each line matching a pattern unless the previous line is already empty

sedtext processing

I need to add a new line before any line containing a pattern where we can assume that the pattern is always the first string of the current line. For example

This is a
pattern
This is a
pattern

I can add a new line with the sed command

sed -i 's/pattern\+/\n&/g' file

to get the output

This is a

pattern
This is a

pattern

To prevent multiple new lines being added (in case of multiple execution) I want to check whether the line before the pattern is empty. I know I can do that with

if [ "$line" == "" ]; then

But how do I determine the previous line, of a matching pattern, in the first place?

EDIT: Pattern can occur multiple times.

Best Answer

You could store the previous line in the hold space:

sed '
 /^pattern/{
   x
   /./ {
     x
     s/^/\
/
     x
   }
   x
 }
 h'

It would be more legible with awk though:

awk '!previous_empty && /pattern/ {print ""}
     {previous_empty = $0 == ""; print}'

Like the GNU implementations of sed has a -i option for in-place editing, the GNU implementation of awk as -i inplace for that.

Related Solutions

Insert Text from File Inline After Matching Pattern – Sed and Awk Tips

In your linked question there is already good awk answer, just modify it a little bit by using printf instead of print to insert the content without newline:

awk '/First/ { printf $0; getline < "File1.txt" }1' infile.txt

Result:

Some Text here
FirstThis is text to be inserted into the File.
Second
Some Text here

You may want to add space or other delimeter after "First" with printf $0 " "; ...

If inserted file has many lines then:

awk '/First/{printf $0; while(getline line<"File1.txt"){print line};next}1' infile.txt

Result:

Some Text here
First[
    {
        "foo": "bar", 
        "baz": "biff",
        "data": [
            {
                "a": 1945619, 
                "b": [
                    {
                        "c": 512665, 
                        "d": "futz"
                    }
                ]
            }
        ]
    }
]
Second
Some Text here

Find each line matching a pattern but print only the line above it

If the pattern cannot occur on consecutive lines you can simply run

sed '$!N;/.*\n.*PATTERN.*/P;D' infile

I've explained here how the N;P;D cycle works. The difference is that here the first line in the pattern space is printed only if the second one matches, otherwise it's deleted.

If the pattern can occur on consecutive lines the above solution will print a line that matches if it's followed by another line that matches.
To ignore consecutive matches add a second condition to print the first line in the pattern space only if it doesn't match:

sed '$!N;/.*\n.*PATTERN.*/{/.*PATTERN.*\n.*/!P;};D' infile

Another way, using the hold buffer.
If you want to ignore consecutive matches:

sed '/PATTERN/!{              # if line doesn't match PATTERN
h                             # copy pattern space content over the hold buffer
d                             # delete pattern space
}
//{                           # if line matches PATTERN
x                             # exchange pattern space with hold space
//d                           # if line matches PATTERN delete it
}' infile

or, in one line

sed '/PATTERN/!{h;d;};//{x;//d;}' infile

If you don't want to ignore consecutive matches:

sed '/PATTERN/!{              # if line doesn't match PATTERN
h                             # copy pattern space content over the hold buffer
d                             # delete pattern space
}
//x                           # if line matches PATTERN exchange buffers
' infile

or, in one line

sed '/PATTERN/!{h;d;};//x' infile

Though keep in mind the solutions that use the hold buffer will print a leading empty line if the first line in your file matches.

Best Answer

Related Solutions

Insert Text from File Inline After Matching Pattern – Sed and Awk Tips

Find each line matching a pattern but print only the line above it

Related Question