Outlook 2010: set default zoom level for reading messages

microsoft-outlookmicrosoft-outlook-2010

When opening messages in Outlook 2010 (not using the reading pane) you can hold control down and roll your mouse wheel up to zoom in on the message, but you have to do this each time you open a message.

Is there a way to set the default zoom level for messages? For example, set the zoom level to default to 150% for each message.

Failing that is there any other way I can make the default text to larger when reading messages? (without changing the DPI settings in the OS)

Best Answer

This is normal behavior for Outlook 2010; it does not retain zoom adjustments. The only option you have is to create a macro that runs at launch or to use an Add-In for zoom control.

Here is how to add VBA to set the zoom level at application start-up.

  1. Set your macro security to Low.
  2. Open the VB editor using Alt+F11
  3. Expand Project1 to show ThisOutlookSession
  4. Paste the macro in ThisOutlooksession
  5. Set a reference to Microsoft Word in Tools, References
  6. Click in the Application_Startup macro and press the Run button to kick start it without restarting Outlook.
Option Explicit
Dim WithEvents objInspectors As Outlook.Inspectors
Dim WithEvents objOpenInspector As Outlook.Inspector
Dim WithEvents objMailItem As Outlook.MailItem

Private Sub Application_Startup()
Set objInspectors = Application.Inspectors
End Sub

Private Sub Application_Quit()
Set objOpenInspector = Nothing
Set objInspectors = Nothing
Set objMailItem = Nothing
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
If Inspector.CurrentItem.Class = olMail Then
Set objMailItem = Inspector.CurrentItem
Set objOpenInspector = Inspector
End If
End Sub

Private Sub objOpenInspector_Close()
Set objMailItem = Nothing
End Sub

Private Sub objOpenInspector_Activate() 
Dim wdDoc As Word.Document
Set wdDoc = objOpenInspector.WordEditor
wdDoc.Windows(1).Panes(1).View.Zoom.Percentage = 150
End Sub

Note: The second to last line is where you set the zoom percentage. Change the 150 to the percent you desire.

Source - Adjusting Outlook's Zoom setting in Email

Related Question