Excel – How to hide 0-value data labels in an Excel Chart

The quick and easy way to accomplish this is to custom format your data label.

1. Select a data label.
2. Right click and select Format Data Labels
3. Choose the Number category in the Format Data Labels dialog box.
4. Select Custom in the Category box.
5. In the format code box, enter 0%;-0%; and click Add.
6. Close out of your dialog box and your 0% labels should be gone.

This works because Excel looks to your custom format to see how to format Postive;Negative;0 values. By leaving a blank after the final ;, Excel formats any 0 value as a blank.

I think this falls into the world of VBA. Working on individual data labels is fairly limited otherwise.

Here is code that will iterate through the series in a chart, their data points, and then delete those labels which correspond to a point with Value=0.

There is a line of code in there (commented) that will add the data labels again to all of the points to reset them. If you just want to delete, then you can skip this line.

Edit: added in an outer loop on ActiveSheet.ChartObjects in order to process all of the charts on a sheet.

Sub RemoveZeroValueDataLabel()

    'runs through every chart on the ActiveSheet
    Dim cht As Chart
    Dim chtObj As ChartObject

    For Each chtObj In ActiveSheet.ChartObjects
        Set cht = chtObj.Chart

        Dim ser As Series
        For Each ser In cht.SeriesCollection

            Dim vals As Variant
            vals = ser.Values

            'include this line if you want to reestablish labels before deleting
            ser.ApplyDataLabels xlDataLabelsShowLabel, , , , True, False, False, False, False

            'loop through values and delete 0-value labels
            Dim i As Integer
            For i = LBound(vals) To UBound(vals)
                If vals(i) = 0 Then
                    With ser.Points(i)
                        If .HasDataLabel Then
                            .DataLabel.Delete
                        End If
                    End With
                End If
            Next i
        Next ser
    Next chtObj
End Sub

This answer grabs Values from the Series using the technique detailed here.

Here is the result on some random data where a couple of 0 value bars have had their data labels deleted.