Excel – Generate Combinations in Excel

In Excel, merging multiple cells into one cell will keep the upper-left most data only. For example, if you merge the range A2:A6, only A2 will keep its value and A3:A6 will be blank. So, merged cells will be troublesome in your case. Instead, you can unmerge the cells in your first column, fill them with the related values (document names), and then use Filtering. Moreover, you can also use Pivot Tables (Insert > Pivot Table). Drag your first column's header (Document name) to Row Labels (in the Pivot Table Field List), and other column headers to Column Labels. You can change the design of your Pivot Table in whatever way you like.

Your example indicated 12 items. This code (supplied by John Coleman in 2005) will list the 4095 permutations of the list in column B. There are 2^N-1 items:

Sub MAIN()
    B = Array("a", "b", "c", "d", "q", "w", "e", "r", "z", "x", "v", "p")
    Call GrayCode(B)
End Sub

Function GrayCode(Items As Variant) As String
    Dim CodeVector() As Integer
    Dim i, kk As Integer
    Dim lower As Integer, upper As Integer
    Dim SubList As String
    Dim NewSub As String
    Dim done As Boolean
    Dim OddStep As Boolean

    kk = 1
    OddStep = True
    lower = LBound(Items)
    upper = UBound(Items)

    ReDim CodeVector(lower To upper) 'it starts all 0
    Do Until done
        'Add a new subset according to current contents
        'of CodeVector

        NewSub = ""
        For i = lower To upper
            If CodeVector(i) = 1 Then
                If NewSub = "" Then
                    NewSub = "," & Items(i)
                Else
                    NewSub = NewSub & "," & Items(i)
                End If
            End If
        Next i
        If NewSub = "" Then NewSub = "{}" 'empty set
        SubList = SubList & vbCrLf & NewSub
        Cells(kk, 2) = Mid(NewSub, 2)
        kk = kk + 1
        'now update code vector
        If OddStep Then
            'just flip first bit
            CodeVector(lower) = 1 - CodeVector(lower)
        Else
            'first locate first 1
            i = lower
            Do While CodeVector(i) <> 1
                i = i + 1
            Loop
            'done if i = upper:
            If i = upper Then
                done = True
            Else
                'if not done then flip the *next* bit:
                i = i + 1
                CodeVector(i) = 1 - CodeVector(i)
            End If
        End If
        OddStep = Not OddStep 'toggles between even and odd steps
    Loop
    GrayCode = SubList
End Function

Reference:

John Coleman Code

You can change/add/remove items by changing the Array(). Too many will overflow the limits to the number of items in a colummn.