AutoHotkey – How to Restore or Activate a Minimized Window

autohotkeywindows 10

I have created the following script in an attempt to have one hotkey that launches the calculator, or, if it is already open, 'activates' the window, or, if it is already activated, closes the calculator. It all works fine accept that if the calculator is minimized it fails to restore it. As far as I can tell I have done everything right. I don't get it what the problem is. The AHK documentation claims that you if you call WinActivate on a minimized window it will first restore that window, but that is a lie. If I uncomment the MsgBox line I still get a message when the window is minimized, but it is powerless to do anything more.

If WinExist("Calculator") {
;MsgBox Calculator Exists.
IfWinActive
    WinKill
Else
    WinGet, winState, MinMax
    If (winState = -1)
        WinRestore, Calculator
    WinActivate, Calculator
}
Else {
    run calc
    WinActivate, Calculator
}

Best Answer

Which OS are you on? Your code works for me on Win10 if I add the ahk_class to the title:

If WinExist("Calculator ahk_class ApplicationFrameWindow") 
{
    ;MsgBox Calculator Exists.
    IfWinActive
        WinClose
    Else
    {
        WinGet, winState, MinMax
        If (winState = -1)
        {
            WinRestore
            WinActivate
        }
    }
}
Else 
{
    run calc
    WinWait, Calculator
    WinActivate
}

Related Solutions

Autohotkey script to exit VMWare window

Russell's answer gets you a large chunk of the way there using RDP as an example. It's a little harder to detect that you're in vsphere/vmware console but can be done with the below. I've commented the changes/additions

#UseHook
#SingleInstance force

; A window's title can contain WinTitle anywhere inside it to be a match
SetTitleMatchMode, 2

setTimer, windowWatch, 500

windowWatch:
  ; if rdp OR (partial title matching vsphere AND you are in the console captured section)
  if WinActive("ahk_class TscShellContainerClass") or (WinActive(" - vSphere Client") and Control("MKSEmbedded1")) {
    if (!active) {
      active := true
      Sleep 50
      suspend off
    }
  } else {
    active := false
    suspend on
  }
return

; return ClassNN of mouse position
Control(ClassNN) { 
    MouseGetPos,,,,control 
    return (ClassNN = control) 
}

I use this to allow play/pause media keys to work in both rdp/vsphere

Media_Play_Pause::
  Sleep 50
  Run "C:\Foobar2000\foobar2000.exe" /playpause
return

Autohotkey script to toggle minimize/restore

Toggling between Minimize and Restore doesn't make much sense as you'll need the Window in focus (or some other way) to send it the command.

Assuming you really mean toggle between Maximize and Restore...

I have these in my AutoHotkey.ahk. You'll be interested in the "F3" mapping which really is Ctrl-Shift-3 in my setup.

;-----------------------------------------------------------------------------------
; Shortcut keys to Minimize, Maximize/Restore the current Window {{{1
; Meant to operate as the 3 right buttons on the window
;
;                                         Alt-F2         = AutoHotkey
;                                            Alt-F3      = AutoHotkey
;                                                 Alt-F4 = Default Windows
; +----------------------------------------------------+
; |                                        [_] [ ] [X] |
; +----------------------------------------------------+
; |                                                    |
; |                                                    |
;-----------------------------------------------------------------------------------
!F2:: WinMinimize, A
!F3::
WinGet MX, MinMax, A
If MX
WinRestore A
Else WinMaximize A
return

^+2:: WinMinimize, A
^+3::
WinGet MX, MinMax, A
If MX
WinRestore A
Else WinMaximize A
return
^+4:: WinClose, A

Best Answer

Related Solutions

Autohotkey script to exit VMWare window

Autohotkey script to toggle minimize/restore

Related Question