Sending images automatically via email to a specific email address

applescriptautomatoremailmail.appscript

I have a little problem. Maybe you can help me with it.
I am shooting many portraits for a client. Like 200 each day.
I have to email every single Portrait via Mail. A gallery with all portraits in one is not allowed because of privacy stuff.
The client wants definitely emails.
I tried to program an Applescript/Automator action to do this automatically.

My plan is to name all the files like so: name@client.com_2847.jpg and let the action do the rest of the magic.

It kind of works, except that i am not able to extract the mail address from the jpg file.

How do I extract the Email from the file (for example deleting the last 9 digits) and putting it in as the recipient?

I saw a similar question here: Automator -> send file to email (from filename)

but for some reason I get many syntax errors.

thanks!

Best Answer

Since in your question, you did not include any code, error message(s), or even how you were implementing your solution, I'll offer the following as an example of how I might automate the task at hand. Note that while I looked at the link in your question, nonetheless, since it was for Outlook and you've tagged the question with mail.app, I'm going to ignore what was linked and proceed my way from scratch.

In this example scenario, I created a hierarchical folder structure under ~/Photos, e.g. ~/Photos/Clients/Name/Emailed Photos, and this is the folder that I'll drag the target photos to, that have the naming convention e.g. name@client.com_2847.jpg, and the folder to which the Automator Folder Action workflow will be attached to.

In Automator:

File > New
Select, Folder Action and click the Choose button.
In the Folder Action receives files and folders added to Choose Folder list box, select: Other...
Navigate to the target folder, the one the action is to be applied to, select it and click the Choose button.
Add a Run AppleScript action to the newly created Folder Action workflow.
Highlight the default AppleScript code, and delete it.
Copy and paste the AppleScript code, shown below, into the Run AppleScript action.
Save the Folder Action as, e.g.: Email Photos to name@client
- This will be saved as, e.g.:
  ~/Library/Workflows/Applications/Folder Actions/Email Photos to name@client.workflow

Now when you drag photos having the naming convention, e.g. name@client.com_2847.jpg to the target folder, e.g. ~/Photos/Clients/Name/Emailed Photos, one email for each photo will be created and the target file attached. Initially the email will not be automatically sent until you uncomment, remove the -- from in front of the -- send theMessage line of code, and save the changes. This is initially commented out so you can test with one file and get your subject and message setup to meet your needs. I'd use a file that has your email address in it for testing purposes, doing one at first then several at one time.

The email message subject and content are initially set to "Portraits" and Photo attached." respectively, as placeholders. Additionally there is another line of commented code, -- delay 2, above the -- send theMessage line of code that you may need/want to implement if adding a large number of files at the same time to the target folder which has the Folder Action attached, as rapid sending may cause issues. Note that the value of the delay command may need to be adjusted higher as appropriate to accommodate the conditions and you'll just have to do some testing to see what works for you. While I did do some testing, I used a very small file (3 KB) that I replicated and sequentially named for testing purposes. I'll assume your photos will be much larger in size.

AppleScript code:

property theMessageSubject : "Portraits"
property theMessageContent : "Photo attached."

on GetTheRecipientNameFrom(theFilename)
    --      # Get the filename portion of the alias passed to the Folder Action.        
    set AppleScript's text item delimiters to ":"
    set theFilename to last item of text items of theFilename
    set AppleScript's text item delimiters to ""
    --      # Make sure the filename contains both an '_' and "@".
    --      # This doesn't guarantee a properly formed email address,
    --      # however it does attempt to validate what was passed as one.   
    if theFilename contains "_" and theFilename contains "@" then
        set AppleScript's text item delimiters to "_"
        set theFilename to first item of text items of theFilename
        set AppleScript's text item delimiters to ""
        return theFilename
    else
        return ""
    end if
end GetTheRecipientNameFrom

on run {input, parameters}
    set fileCount to (count of items of input)
    set i to 1
    repeat fileCount times
        set theMessageAttachment to item i of input
        set theRecipient to GetTheRecipientNameFrom(theMessageAttachment as string)
        if theRecipient is not equal to "" then
            tell application "Mail"
                activate
                set theMessage to make new outgoing message with properties {visible:true, subject:theMessageSubject, content:theMessageContent & linefeed & linefeed}
                tell theMessage
                    make new to recipient at end of to recipients with properties {address:theRecipient}
                end tell
                tell content of theMessage
                    make new attachment with properties {file name:theMessageAttachment} at after last paragraph
                end tell
                set i to i + 1
                -- delay 2
                -- send theMessage
            end tell
        else
            set i to i + 1
        end if
    end repeat
end run

Note that as coded, if a file dropped into the target folder, the folder to which the Folder Action is attached, does not conform to the naming convention of e.g. name@client.com_2847.jpg, then no email for that file should be created, unless the portion of the filename preceding the underscore contains the @ symbol and any other characters. In other words, the only error checking the code, as is, attempts to validate is the filename contains a valid email address only on the premise if it has both an underscore and @ symbol, then it assumes the filename conforms to e.g. name@client.com_2847.jpg. More strict error checking could be coded, however I'll leave that to you if what's presented isn't adequate.

Additionally, other forms of general error checking could be implemented, i.e. making sure the file was actually attached before sending, etc., however this answer is meant to be a simple example, not necessarily a fully coded solution. The onus is on you to insure you implement appropriate error checking as conditions warrant.

As you might be able to tell by the images below, I wrote and tested this in a pre OS X 10.9 environment, OS X 10.8.6 to be specific and I have "Enable access for assistive devices" checked in Accessibility preferences. In OS X 10.9 and later, including the latest version of macOS, Sierra, you may need to add Mail and or Automator to System Preferences > Security & Privacy > Privacy > Accessibility in order for the Folder Action to work. I'm not in a position to test in those versions at the moment, however if it doesn't work for you, then add these apps accordingly.

Related Solutions

Automator -> send file to email (from filename)

I've tried with Automator without succeeding looping through dropped files.

Here's a folder action script that does what you want, and how to attach it to a folder :

1. Open AppleScript Editor

2. Paste the following script into a new document

property mail_subject : "An image for you"
property mail_plain_content : "Attached you will the image you required." & return & return & "Best Regards" & return & "Automator"
property mail_html_content : "Attached you will the image you required.<br><br>Best Regards<br>Automator"

on adding folder items to this_folder after receiving these_items
    processItems(these_items)
end adding folder items to

on processItems(these_items)
    repeat with i from 1 to (count of these_items)
        set this_item to item i of these_items
        if isFolder(this_item) then
            processItems(getFolderItems(this_item))
        else
            processFile(this_item)
        end if
    end repeat
end processItems

on processFile(this_file)
    set mail_address to RemoveExtension(getFileName(this_file))
    tell application "Microsoft Outlook"
        set newMessage to make new outgoing message with properties {subject:mail_subject, plain text content:mail_plain_content, content:mail_html_content}
        tell newMessage
            make new recipient with properties {email address:{address:mail_address}}
            make new attachment with properties {file:this_file as alias}
            send
        end tell
        activate
    end tell
end processFile

on isFolder(this_item)
    tell application "System Events" to return (exists folder (this_item as string))
end isFolder

on RemoveExtension(this_name)
    -- This function comes from :
    -- http://www.macosxautomation.com/applescript/sbrt/index.html
    if this_name contains "." then
        set this_name to (the reverse of every character of this_name) as string
        set dot_offset to the offset of "." in this_name
        set this_name to (text (dot_offset + 1) thru -1 of this_name)
        set this_name to (the reverse of every character of this_name) as string
    end if
    return this_name
end RemoveExtension

on getExtension(this_name)
    if this_name contains "." then
        set this_name to (the reverse of every character of this_name) as string
        set dot_offset to the offset of "." in this_name
        set this_name to (text 1 thru (dot_offset - 1) of this_name)
        set this_name to (the reverse of every character of this_name) as string
        return this_name
    else
        return ""
    end if
end getExtension

on getFileName(this_file)
    tell application "Finder" to return name of this_file
end getFileName

on getFolderItems(this_folder)
    tell application "Finder" to return items of this_folder
end getFolderItems

3. Save it in your ~/Library/Scripts/Folder Action Scripts Folder

Menu File > Save

Go to the right folder : press cmd+G and paste:
~/Library/Scripts/Folder Action Scripts
and click Go

Save as : Image - Email using name as address.scpt (for example)
Format : Script

4. Create a new folder that will be watched for added items

5. Associate the script to the folder

In the Finder, right click on your folder, then select Services > Folder Actions Setup Select the new created Image - Email using name as address.scpt script

You're done, drop a file whose name is an address, mail will be sent.

Expand Sending Email with Applescript

Try something like this:

set csv to "name@example.com,7/14
name2@example.com,7/15"
--set csv to read "/Users/username/Documents/file.csv" as «class utf8»

set text item delimiters to ","
set y to year of (current date)
repeat with l in paragraphs of csv
    set d to (date (text item 2 of l & "/" & y))
    if date string of (current date) is date string of (d - 1 * days) then
        tell application "Mail"
            tell (make new outgoing message)
                set subject to "subject"
                set content to "content"
                make new to recipient at end of to recipients with properties {address:text item 1 of l}
                send
            end tell
        end tell
    end if
end repeat

You can run the script every day after midnight (if the computer is awake) by running EDITOR=nano crontab -e and adding a line like 1 0 * * * osascript ~/Scripts/some\ script.scpt.

The recognized date formats depend on the settings selected in System Preferences. I don't know how to get an email address for a first name and last name.

Best Answer

Related Solutions

Automator -> send file to email (from filename)

Expand Sending Email with Applescript

Related Question