Need to automate an SMB path into a UNC path before sending to Win10 clients

applescriptautomatorNetworksmb

New here, but I'm having difficulty putting together an AppleScript that will basically take an SMB link and turn it into a UNC link before I send it over to a couple of Win10 clients.

All same network, we're all using a SNS NAS and it's for Adobe Premiere links. We can do this all manually, but the editors don't have time/patience to convert each link. We're looking for an automated script that we could integrate as a service that will convert selected text.

I found the article below, but it's the reverse to what we're looking for. I tried reversing all of the functions in it but wasn't able to get it to run properly.

https://gist.github.com/anonymous/2211017

It'd also be awesome if the 'service' that is created simple copies the entry into the clipboard so that the end-user can paste it into a couple of different things like email and Slack messenger.

Hopefully someone can help or steer me in the right direction. I've been scouring Google for this for about a week.

EDIT** Examples below

Old path
'smb://server/folder'

New path
'\\server\folder'

Best Answer

NOTE: This answer is intended only as an example when the SMB Path, aside from the colon, slashes and backslashes and without spaces, only contains alphanumeric characters in the name! If you need to account for anything else, i.e. read the comments to this answer, you'll need to modify the code according to your needs. That said, in all of my years as a Network Systems Administrator and Network Systems Engineer I never created shares containing spaces or other then the need for colons, slashes, backslashes and alphanumeric characters and therefore this simple example is all that I'd need to translate any, e.g. smb://server/folder to \\server\folder, SMB Path I ever used to a UNC Path. YMMV!

In Automator, create a new Service workflow, then add a Run AppleScript action to it while replacing the default AppleScript code with the code below:

on searchReplace(theText, SearchString, ReplaceString)
    set OldDelims to AppleScript's text item delimiters
    set AppleScript's text item delimiters to SearchString
    set newText to text items of theText
    set AppleScript's text item delimiters to ReplaceString
    set newText to newText as text
    set AppleScript's text item delimiters to OldDelims
    return newText
end searchReplace

on run {input, parameters}
    set selectedText to item 1 of input as string
    set convertedText to searchReplace(selectedText, "smb://", "\\\\")
    set convertedText to searchReplace(convertedText, "/", "\\")
    set the clipboard to convertedText as string
    return convertedText
end run

Then save the Service as: Convert SMB Path to UNC Path

Now Convert SMB Path to UNC Path will appear on the Services menu or Services context menu when text is selected and when the Service is used, the UNC Path is placed on the Clipboard. (This of course assumes the selected text was actually an SMB Path, otherwise what's placed there is just whatever text was selected when the Service was run which will include any substitutions made.)

Example SMB Path smb://server/folder will be converted to UNC Path \\server\folder and placed on the Clipboard.

Note: Note the settings of the Service in the image below. The Output replaces selected text checkbox is unchecked. You may check it, if that's what you want, however, if the selected text is not actually replaceable then the Service will not appear on the Services menu or Services context menu.

Related Solutions

MacOS – How to automate pasting of password into SecurityAgent

With thanks to input from markhunte and tetsujin, I came up with the following solution. With all things considered, the exact requirements evolved to the following:

Ensure a SecurityAgent dialog is actually present so that script doesn't run otherwise.
Reposition the SecurityAgent dialog because it can readily get in the way in its default position.
Display a message which will stay on top of 1Password, but is not generated through 1password, instructing the user to select the correct item in 1Password
Automatically copy the password for current 1Password item
Delay the script long enough for the password to actually end up in the clipboard, before the script attempts pasting it.
Paste the clipboard into the SecurityAgent, and submit it.

I came up with the following solution:

set appName to "SecurityAgent"
set passApp to "1Password 5" (* set this to the name of your password manager *)

tell application "System Events"
     if not (exists window 1 of process appName) then -- test if SecurityAgent window exists
         return -- abort if SecurityAgent window does not exist
     end if
 end tell
 tell application "System Events"
    set position of window 1 of process appName to {10, 10} -- move SecurityAgent window out of the way 
 end tell
 tell application passApp
      activate -- bring 1Password to the forefront, run it if not running
 end tell
 tell application "System Events"
    tell application "SystemUIServer"
      set answer to display dialog "Make sure correct 1Password item is actively selected (i.e. click it again if it was previously selected), then click “Continue” to proceed." buttons {"Continue"}
    end tell
    tell process passApp
    (* If you are not using 1Password, you may need to change the menu item clicks, below, to whatever is correct in your particular password manager *)
        click menu item "copy password" of menu "item" of menu bar 1
        delay 1
        set appData to the clipboard
    end tell
    tell application "System Events"
        tell process appName
            set value of text field 1 of window 1 to appData
            if exists (text field 2 of window 1) then
                set value of text field 2 of window 1 to appData
                click button 1 of window 1
            else
                click button 2 of window 1
            end if
         end tell
     end tell
end tell

I made the whole script conditional on the presence of SecurityAgent, because this script will be assigned to a keyboard shortcut, and if that key combination is inadvertently selected by the user, I'd rather they not be bothered with an unexpected script process.

If there are ways in which I could refine or improve this solution, please advise. I am very happy to be learning more about AppleScript.

FINAL UPDATES: Had to make one final change. It turned out the button numbers for CANCEL and OK change around from the SecurityAgent instance for creating an encrypted disk/disk-image, and for when opening an encrypted disk/disk-image. So I had to modify the IF THEN statement right near the end to handle each scenario.

Mac – Need the automator script to display the regular shutdown prompt before shutting down

Use the menu item instead:

tell application "Finder" to activate
tell application "System Events"
    tell process "Finder"
        click menu item "Shut Down…" of menu 1 of menu bar 1
    end tell
end tell

If you use another system language than English use the proper shut down command instead. At least in OS X 10.11 you have to allow Script Editor/the resulting app to control your computer in System Preferences -> Security -> Privacy -> Accessibility.

You have to copy the menu item exactly including spaces. E.g. the three dots are not three dots but an ellipsis: alt; -> … (en-US keyboard layout)

Best Answer

Related Solutions

MacOS – How to automate pasting of password into SecurityAgent

Mac – Need the automator script to display the regular shutdown prompt before shutting down

Related Question