MacOS – how to auto download a certain attachment in mail

applescriptemailmacosmail.app

I have looked on stack exchange and other sites for a simple applescript. I have found more complex scripts that it's hard for me to understand (not knowing a lot about the applescript syntax). So, here's my dilemma:

I need to automatically download an attachment (i.e. named "blank expense report") to a specific folder (i.e. "Inbox"). That's it. I can setup the mail rule with parameters to find the attachment I'm looking for:

enter image description here

I just need a simple script to download the attachment.

I have looked at these but just got confused trying to alter them and actually messed up some non-essential files on my computer. So, I'll stop copying and pasting code and just ask for some help.

Questions I looked at before this.

Save attachments from Mail.app based on subject

Automatically Save Attachments in Mail.app in 10.8 Mountain Lion

Best Answer

This is an edited version — quite possibly not the best one — of the script shown in this answer to the Automatically Save Attachments in Mail.app in 10.8 Mountain Lion thread, I've tested it and it works:

using terms from application "Mail"
    on perform mail action with messages theMessages for rule theRule
        tell application "Mail"
            repeat with eachMessage in theMessages
                repeat with theAttachment in eachMessage's mail attachments
                    set attachmentName to name of theAttachment
                    if attachmentName is "blank expense report" then
                        set savePath to "Macintosh HD:Users:yourUsername:Inbox:" & attachmentName
                        try
                            save theAttachment in file (savePath)
                            on error err
                            display display "The Following Error Occurred:" & err
                        end try
                    end if
                end repeat
            end repeat
        end tell
    end perform mail action with messages
end using terms from

This script will save the attachment named "blank expense report" in a named "Inbox" at Machintosh HD:Users:yourUsername:Inbox. Be sure to change the value of savePath variable accordingly to your needs.

Attaching other Messages in Mail.app (OS X Lion)

Create a new message (⌘N)
Return to your inbox
Click and hold on the message you want to attach until it turns into a letter icon
(Still holding down) drag and drop the icon into the new message window

Repeat steps 2 through 4 for as many messages as you want to attach.

MacOS – Automatically Save Attachments in Mail.app in 10.8 Mountain Lion

Try this.

   using terms from application "Mail"
    on perform mail action with messages theMessages for rule theRule
        -- The folder to save the attachments in (must already exist)


        -- Save in a sub-folder based on the name of the rule in Mail

        set subFolder to name of theRule
        tell application "Finder"
            set attachmentsFolder to ((path to home folder as text) & "Dropbox:Attachments") as text
            if not (exists folder subFolder of folder attachmentsFolder) then
                make new folder at attachmentsFolder with properties {name:subFolder}
            end if
        end tell
        tell application "Mail"

            repeat with eachMessage in theMessages

                set {year:y, month:m, day:d, hours:h, minutes:min} to eachMessage's date sent
                set timeStamp to ("" & y & "-" & my pad(m as integer) & "-" & my pad(d) & "-" & my pad(h) & "-" & my pad(min))

                try
                    -- Save the attachment
                    repeat with theAttachment in eachMessage's mail attachments

                        set originalName to name of theAttachment
                        set savePath to attachmentsFolder & ":" & subFolder & ":" & timeStamp & " " & originalName
                        try
                            save theAttachment in file (savePath)
                        end try
                    end repeat

                    display dialog subFolder
                end try
            end repeat

        end tell
    end perform mail action with messages
end using terms from

-- Adds leading zeros to date components
on pad(n)
    return text -2 thru -1 of ("00" & n)
end pad

I have posted a more general Automatically Save Attachments in Mail.app on my blog

Questions I looked at before this.

Best Answer

Related Solutions

MacOS – Mac Mail: Add other message as attachment

Attaching other Messages in Mail.app (OS X Lion)

MacOS – Automatically Save Attachments in Mail.app in 10.8 Mountain Lion

Related Question