How to close specific URLs with Applescript

applescripturl

I'm trying to write a little applescript that closes tabs that have URLs that do not contain certain text, but I can't get it to work.

Right now, my script closes every tab regardless of the URL. When it should only close specific URLs.

Can anyone tell me where I've gone wrong?

Here's the script…

tell windows of application "Google Chrome" to close (tabs whose URL does not contain {"business.facebook", "pinterest"} as text)

Best Answer

This works:

tell windows of application "Google Chrome"
    close (tabs whose URL does not contain "business.facebook" and URL does not contain "pinterest")
end tell

In an AppleScript whose clause you need to spell out each criteria fully and join them with a logical operator. You tried to use a list to make an implicit and; that makes sense to the human brain, but AppleScript can't parse it.

Related Solutions

AppleScript – “Close tabs to right of current tab” in Safari 7

Your script still worked in my limited testing, but you could also try something like this:

tell window 1 of application "Safari"
    close (tabs where index > (get index of current tab))
end

Open a new Safari window in the current Space from Terminal with multiple tabs (URLs)

Here is an AppleScript that should help you. Open AppleScript Editor and save this as a script. I have modified the source that I found here to support taking arguments on the command line.

Use it like this:

osascript new_window.scpt http://www.google.com http://www.stackoverflow.com

Of course, replace the URLs above with your own URLs.

new_window.scpt

on run argv
    tell application "Safari"
        if (count argv) = 0 then
            -- If you dont want to open a new window for an empty list, replace the
            -- following line with just "return"
            set {first_url, rest_urls} to {"", {}}
        else
            -- `item 1 of ...` gets the first item of a list, `rest of ...` gets
            -- everything after the first item of a list.  We treat the two
            -- differently because the first item must be placed in a new window, but
            -- everything else must be placed in a new tab.
            set {first_url, rest_urls} to {item 1 of argv, the rest of argv}
        end if

        make new document at end of documents with properties {URL:first_url}
        tell window 1
            repeat with the_url in rest_urls
                make new tab at end of tabs with properties {URL:the_url}
            end repeat
        end tell
        activate
    end tell
end run

You could even create an alias for this in Terminal and be able to use it easier. I would add the following to ~/.bash_profile:

alias newwindow='osascript /path/to/new_window.scpt'

Call newwindow whatever you want. Save .bash_profile and restart Terminal for it to work.

In case anyone is looking for a similar solution for Google Chrome, here is a different take on the same idea.

chrome_new_window.scpt

on run argv
    tell application "Google Chrome"
        if (count argv) = 0 then
            make new window
        else
            tell (make new window)
                set URL of active tab to item 1 of argv
                repeat with the_url in the rest of argv
                    open location the_url
                end repeat
            end tell
        end if
        set active tab index of first window to 1
        activate
    end tell
end run