Google Chrome won’t open URL files by double click

Open in Chrome Service

You can make a Service in 10.6 or 10.7 using Automator that will open a selected URL in Chrome.

Here's how:

1. Open Automator

2. When Automator asks you to Choose a type for your document window, select Service

3. Change the "Service receives selected" drop-down to "URLs"

4. Add a Run AppleScript action (found under the Automator Library, or just search) by dragging from the left pane to the right
5. Copy the code below to the text field (replacing all the existing text)
6. Save and give the service a name (it will be added automatically to the services menu)

Code:

on run {input}
    set theURL to input
    tell application "Google Chrome"
        if not (exists first window) then
            make new window
            set URL of last tab of first window to theURL
        else
            tell first window
                set newTab to make new tab with properties {URL:theURL}
            end tell
        end if
        activate
    end tell
end run

This will open any selected URL in Safari or other application in Chrome, either in a new tab in the most recent window, or a new window if there is no open Chrome window. To access it, right-click and under the Services item at the bottom of the menu, you should see an item with the name you assigned.

One important caveat: OS X seems to be a bit picky/buggy about passing link to this sort of service. It works fine if you have text selected as a URL, but it only seems to work on some links. If I discover a better method, I'll update this post with it.

You may also need to restart Safari for the service to appear.

As far as I know, there is no way to associate .webloc files with a specific application. Your best bet would probably be to use some AppleScript.
I made a little script that lets you generate tiny little AppleScript applications that open in the browser that you select upon creation (OmniWeb, Safari, or Chrome).

You can download the script here, or compile it yourself from the code below.

set theURL to text returned of (display dialog "What URL would you like to bookmark?" with title "Enter URL" default answer "http://")
set theApp to (choose from list {"OmniWeb", "Safari", "Chrome"} with prompt "Which application would you like to associate with the bookmark?" with title "Select Application") as string
set theName to text returned of (display dialog "What would you like to name the bookmark?" with title "Enter Name" default answer "")
set theFolder to choose folder with prompt "Where would you like to save the bookmark?"

if theApp is "OmniWeb" then
    set theScript to "tell application \"OmniWeb\"
    activate
    try
        set theTab to make new tab at end of front browser with properties {address:\"" & theURL & "\"}
        set active tab of front browser to theTab
    on error
        make new browser with properties {address:\"" & theURL & "\"}
    end try
end tell"
else if theApp is "Safari" then
    set theScript to "tell application \"Safari\"
    activate
    try
        set theTab to make new tab at end of tabs of front window
        set the URL of theTab to \"" & theURL & "\"
    on error
        make new document
        set theTab to tab 1 of front window
        set the URL of theTab to \"" & theURL & "\"
    end try
    set current tab of front window to theTab
end tell"
else if theApp is "Chrome" then
    set theScript to "tell application \"Google Chrome\"
    activate
    if (count of windows) = 0 then
        make new window
        set URL of tab 0 of front window to \"" & theURL & "\"
    else
        set URL of (make new tab at end of tabs of front window) to \"" & theURL & "\"
    end if
end tell"
end if

tell application "AppleScript Editor"
    set theDoc to make new document with data theScript
    save theDoc as "application" in ((theFolder as string) & theName & ".app")
end tell

Running that will prompt you for the URL, the browser you want it to open with, and the location to save the 'bookmark'.

You can put this in your Applications or Scripts folder for easy access and invoke it whenever you want to save a URL.