Get text of most recent notification with applescript

applescript

I would like to be able to grab the text of the most recent notification and pass it into an applescript variable. How can I do that?

Edit: here's what I have so far:

on run
    tell application "System Events"
        tell process "NotificationCenter"
            tell first window
                set rawElements to UI elements
            end tell
        end tell
    end tell
end run

This gets me most of the way there, but it doesn't get me the body of the notification, just the label:

Here's the output:

{static text "Macro Cancelled" of window 1 of application process
"NotificationCenter" of application "System Events", image 1 of window
1 of application process "NotificationCenter" of application "System
Events", scroll area 1 of window 1 of application process
"NotificationCenter" of application "System Events", image 2 of window
1 of application process "NotificationCenter" of application "System
Events"}

Best Answer

Using the following example AppleScript code to generate a notification:

display notification with title "Macro Cancelled" subtitle "Cancel All Macros."

In the example notification, Cancel All Macros. is in:

static text of scroll area 1 of window 1 of process "NotificationCenter"

Using:

tell application "System Events" to ¬
    get value of ¬
        static text of ¬
        scroll area 1 of ¬
        window 1 of ¬
        process "NotificationCenter"

It returns:

{"Cancel All Macros.", ""}

As you can see what's returned is a list and will need to be process as such.

Note however, in this example, Cancel All Macros. is actually static text 1 of scroll area 1 and static text 2 of scroll area 1, which is blank, is when display notification uses:

display notification [text] : the body text of the notification

_{Note: The example AppleScript code is just that and does not contain any error handling as may be appropriate. The onus is upon the user to add any error handling as may be appropriate, needed or wanted. Have a look at the try statement and error statement in the AppleScript Language Guide. See also, Working with Errors. Additionally, the use of the delay command may be necessary between events where appropriate, e.g. delay 0.5, with the value of the delay set appropriately.}

With Error Handling:

tell application "System Events" to ¬
    if exists window 1 of ¬
        process "Notification Center" then ¬
        get value of ¬
            static text of ¬
            scroll area 1 of ¬
            window 1 of ¬
            process "NotificationCenter"

Related Solutions

MacOS – Applescript to automate drop-down selection in Mozilla Firefox

Try this

tell application "Firefox"
    activate
    tell application "System Events"
        keystroke tab
        keystroke (key code 125)
        keystroke (key code 125)
        keystroke (key code 125)        
    end tell
end tell

You might not need to activate Firefox if it's the current active app. Them you just need :

tell application "System Events"
    keystroke tab
    keystroke (key code 125)
    keystroke (key code 125)
    keystroke (key code 125)        
end tell

Close all programs after 1min without user interaction

Here you go. A simple script you can setup to run automatically in the background using launchd or other means of your liking...

#
# From: http://www.dssw.co.uk/blog/2015-01-21-inactivity-and-idle-time
# Returns seconds system is idle, ie no user input...
#
set cmd to "echo $((`ioreg -w 0 -c IOHIDSystem | sed -e '/HIDIdleTime/ !{ d' -e 't' -e '}' -e 's/.* = //g' -e 'q'` / 1000000000))"

#
# How many seconds user can be idle before we log them out
#
set maxIdleAllowed to 60

#
# How frequently we check the idle time, in seconds...
#
set checkInterval to 30

#
# We loop forever...
#
repeat
    set secsIdle to 0

    try
        set answer to (do shell script cmd)
        set secsIdle to (answer as number)
    on error
        # May want to do something fancy here...
        exit repeat
    end try

    log secsIdle

    if secsIdle > maxIdleAllowed then
        logUserOut()
    end if

    delay checkInterval
end repeat

on logUserOut()

# Exclude Finder at minimum because bad things happen, so I am told...
set excludedApps to {"Finder"}

tell application "System Events"
    #set oAppList to get id of every application process whose background only is false
    set {processList, idList, pidList, bidList} to the {name, id, unix id, bundle identifier} of (every application process whose background only is false)
end tell

set i to 0
repeat with p in processList
    set i to i + 1

    log "ID: " & item i of idList
    log "PID:" & item i of pidList
    log "Name: " & p
    log "Bundle: " & item i of bidList

    if p is not in excludedApps then
        try
            log "Quit with out saving app with id: " & item i of idList

            # timeout to prevent blocking by certain apps...
            with timeout of 1 second

                # Use bundle id for some odd apps... soffice i'm talking to you!?!
                tell application id (item i of bidList) to quit saving no

            end timeout

        on error
            try
                log "Giving up, killing pid: " & (item i of pidList)
                do shell script "kill " & (item i of pidList)
            end try
        end try
    end if

    delay 1

    log "" & return
end repeat

# Finally, with all apps closed, kill our session...
tell application "loginwindow" to «event aevtrlgo»

end logUserOut

EDIT: Your question has already been answered really, it's just that your action, after idle time, is different. Take a look here at,

How can I automatically launch an application whenever the Mac goes idle?

EDIT2: There you go. Added routine to close apps nicely if possible, and if not, kill them and logs out.

Best Answer

Related Solutions

MacOS – Applescript to automate drop-down selection in Mozilla Firefox

Close all programs after 1min without user interaction

Related Question