I usually use scripts like this instead of Automator services:

try
    set old to the clipboard as record
end try
tell application "System Events" to keystroke "c" using command down
do shell script "export LC_CTYPE=UTF-8; pbpaste | /usr/local/bin/pygmentize -g -f rtf | pbcopy"
tell application "System Events" to keystroke "v" using command down
delay 0.05
try
    set the clipboard to old
end try

• If the clipboard is empty, trying to get it results in an error.
• pbpaste and pbcopy use ASCII if the locale variables are unset. I couldn't get pygmentize -f rtf to work with non-ASCII characters though.
• Without the delay set the clipboard to old would sometimes be run before the text would get pasted.

You can create services like this:

Then give the services shortcuts from System Preferences > Keyboard > Shortcuts > Services.

I prefer using third party applications instead of services to assign shortcuts to scripts though. There has been a bug since 10.7 where the shortcuts for services don't always work until you hover over the services menu from the menu bar (or for example run a service once from the menu bar). There is also a noticeable delay before services are run, and the shortcuts for services don't work when an application that doesn't have a services menu (like Tower) is frontmost.

More examples:

tell application "VLC"
    if playing then
        tell application "System Events" to tell process "VLC"
            click menu item "Pause" of menu 1 of menu bar item "Playback" of menu bar 1
        end tell
    else
        play
    end if
end tell

tell application "VLC"
    set n to 60
    if duration of current item - current time > n then
        set current time to current time + n
    else
        next
    end if
end tell

tell application "VLC"
    set fullscreen mode to not fullscreen mode
end tell

tell application "VLC"
    volumeUp
end tell

Open VLC's dictionary in AppleScript Editor to see all supported terminology.