Can Automator pass multiple lines (e.g. from a shell script) to the New Mail Message action

automatorbashmail.apptext;

I have Automator running a shell script that ends with cat "tempfile.txt". The cat command should output the contents of tempfile.txt. The file tempfile.txt contains just the following three paragraphs over five lines:

1st paragraph Lorem

2nd paragraph Lorem ipsum

3rd paragraph Ut enim

I have this chained in Automator to the "New Mail Message" action. The instructions for this action say that "If text is received from a previous action, the text is appended to the message."

The expected behavior is therefore that the body of the email message contains those three paragraphs. Instead, it contains only the third—shown here:

Below is the relevant part of the workflow. In it we can see in the Results for the shell script that all three paragraphs are being passed to the "New Mail Action." Why does this not put all of the input text file into the message body?

Update (further info): If I swap in the "Create New Outlook Mail Message" action in place of the Mail.app action, all three paragraphs are successfully passed to the body of the new message in Outlook. However, they are passed without line breaks.

Best Answer

It looks like there may be a bug in New Mail Message action in Automator. If you are interested in an AppleScript workaround, where the output of the Run Shell Script action is formed into the content of the new mail message using AppleScript code to create a new mail message, here's an example workaround.

In place of the New Mail Message action use a Run AppleScript action, after the Run Shell Script action, with the following example AppleScript code:

on run {input, parameters}
    set theMessageContent to ""
    repeat with i from 1 to (count of input)
        set theMessageContent to theMessageContent & item i of input & linefeed
    end repeat
    tell application "Mail"
        activate
        set theMessage to make new outgoing message with properties {visible:true, content:theMessageContent}
    end tell
end run

This creates a new message that looks like the following example image.

If you need too, you can add additional properties, as in this example AppleScript code:

on run {input, parameters}
    set theMessageContent to ""
    repeat with i from 1 to (count of input)
        set theMessageContent to theMessageContent & item i of input & linefeed
    end repeat
    tell application "Mail"
        activate
        set theMessage to make new outgoing message with properties {visible:true, subject:"Hello World", content:theMessageContent}
        tell theMessage
            make new to recipient at end of to recipients with properties {name:"John Doe", address:"johndoe@domain.com"}
        end tell
    end tell
end run

Obviously, you'll need to change the value of the additional properties, and or add more properties then shown, to fit your needs. You can look in Mail's AppleScript Dictionary in Script Editor for additional applicable properties.

This creates a new message that looks like the following example image.

Related Solutions

Converting videos in the background using automator and handbrake

First, I'm assuming that you accidentally chopped the '/' character off the front of the path to Handbrake in your example. Second, when you say "hidden mode" you mean run in the background.

What happens if you run the command from the command line?

How do you know the command isn't running when you run it in background mode? Are you doing a "ps" command from the command line to see if it is running or not?

Have you tried adding ">>~/HB_log.txt 2>&1" just before the "&" command so that you get a log of both the output and the errors it might be putting out?

If only the first part of the name is being used then I assume that the quote characters around the name are being stripped - try escaping them with a '\'. Like so '\"/Users/abc/Desktop/TestVidDest/$(basename $f)\" ' and see what happens.

I also suspect that problems with the name might be upsetting the entire line and causing your problem.

I would actually write a shell script that you could test externally and then call your shell script from Automator.

Apple Script not running as expected

As one of the commenters alluded to, "get first message of inbox" probably won't return what you expect.

When retrieving messages using AppleScript, Mail sorts your mailbox accounts alphabetically. Within each account's inbox, messages are sorted newest first. What you have selected in Mail doesn't change the order in which they're returned to AppleScript.

So if you have the following accounts and inbox messages appearing in Mail in this order:

My iCloud
- Message dated 1/5/16
- Message dated 1/10/16
My Gmail
- Message dated 1/10/16
- Message dated 1/5/16

"get first message of inbox" will return the Message dated 1/5/16 from the "My Gmail" account (G comes before i, 1/5/16 comes before 1/10/16).

My guess is that you have more than one account in Mail.

Name the specific mailbox. This will always set theMessage to the newest message in "My Gmail". (The account name is the same name you see in Mail in the list under Inbox).
```
set theMessage to first message in mailbox "INBOX" of account "My Gmail"
```

This is an unusual approach, however, as mail moves, so the first message in your mailbox could become your second message unexpectedly.

Here are a couple of reliable ways to extract data from messages:

Use selected messages (messages you've selected by clicking on them in Mail):

tell application "Mail"
    set theMessages to selection

    -- This block extracts the topics from the messages
    repeat with theMessage in theMessages
        set theMessageText to content of theMessage
        try
            -- Set topic to the string starting just after the hash
            set topic to rich text ((offset of "#" in theMessageText) + 1) thru end of theMessageText
            -- Truncate the topic at the first space
            set topic to rich text 1 thru ((offset of " " in topic) - 1) of topic
        on error
            -- No topic found in message
            set topic to ""
        end try
        log topic

    end repeat
end tell

Mail Rules (run a script on messages that match certain criteria). In Mail, open Preferences > Rules. Create a new rule with "Run AppleScript" as the action. Select "Open in Finder" from the menu that lets you select which script to run. Open Script Editor, and save the code below as a script in the folder Mail opened. Back in Mail, select your saved script as the script to run:

using terms from application "Mail"
    on perform mail action with messages theMessages for rule thisRule
        -- This block extracts the topics from the messages
        repeat with theMessage in theMessages
            set theMessageText to content of theMessage
            try
                -- Set topic to the string starting just after the hash
                set topic to rich text ((offset of "#" in theMessageText) + 1) thru end of theMessageText
                -- Truncate the topic at the first space
                set topic to rich text 1 thru ((offset of " " in topic) - 1) of topic
            on error
                -- No topic found in message
                set topic to ""
            end try
            log topic
        end repeat

    end perform mail action with messages
end using terms from

Best Answer

Related Solutions

Converting videos in the background using automator and handbrake

Apple Script not running as expected

Related Question