Automator to run AppleScript for a shell script

This isn't too difficult to do, you just need to know the right magic. I'll walk you through it.

1. Open Automator, and when prompted to choose a type for your document, select Service. If you're not prompted, just hit ⌘N to make a new automator file.
2. At the top of the rightmost panel, make sure that Output replaces selected text is checked, and the first drop-down is set to text:
   • You can change the any application part to a specific application if you only want it to work in that program.
3. In the Actions Library in the left panel, find Run Shell Script and double click it to add it to the workflow.
4. Change the Shell drop down to /usr/bin/python, and make sure that Pass input is set to stdin.
5. Delete the existing text in the script box, and replace it with the code below.
6. Save it with a descriptive name. Automator will save it in the ~/Library/Services/ folder.
7. Optional: Go to Keyboard Preferences, and find your service in the Services section of the Keyboard Shortcuts tab. You can assign a system-wide shortcut for it there.

Script Code

import sys

for f in sys.stdin:
    print f.replace('-', ' ').replace('%', ' ').replace('&', ' and ').replace('#', ' ').title(),

I'm not really familiar with the Scala language at all, but it looks like the script is only built to take user input for the password, not arguments or stdin, which is what's required for Automator to pass it data.

The shell that Automator runs scripts in is non-interactive, so your script can't directly prompt the user for a password. If you can rework your script to take a password via stdin, you could use an AppleScript wrapper to get a password dialog, if that's what you're hoping for.

If you rework your pgpsign script to take a password from stdin, you can use an Applescript action (with some shell scripting embedded) to display a password dialog and get the results you desire.

Replace your Run Shell Script action in your current workflow with a Run AppleScript action, with the following code:

on run {input, parameters}
    set thePath to quoted form of POSIX path of first item of input as string
    tell application "System Events"
        display dialog "Password:" default answer "" with hidden answer
    end tell
    set pass to text returned of result
    do shell script "cd " & thePath & "; echo " & quoted form of pass & " | perl -ne 'chomp and print' | ~/scripts/pgpsign"
end run

It's not the most straightforward, so I'll run through line by line what it's doing.

on run {input, parameters}
    set thePath to quoted form of POSIX path of first item of input as string

This gets the input from the service (the folder you selected) and turns it into a string that the shell script can make use of.

tell application "System Events"
    display dialog "Password:" default answer "" with hidden answer
end tell
set pass to text returned of result

This pops up a password dialog and stores the result to the pass variable. Ordinarily in AppleScript you don't need the System Events tell portion, but because of some quirks with Automator, it's required here.

do shell script "cd " & thePath & "; echo " & quoted form of pass & " | perl -ne 'chomp and print' | ~/scripts/pgpsign"

This ties it all together and sends the required parameters to your script. First we change to the selected directory (to answer your question in the comments, as your script is written, it is necessary to first cd to the directory you want). Then echo is used to send the password to stdin, and it's piped through the perl portion to strip the trailing newline (which is an annoying characteristic of AppleScript and would otherwise cause a valid password to fail), then piped to your script.

Sorry for giving you a lot to digest, but if you want to use Automator for this, it's probably the easiest way, unless you want to hardcode your password (which is obviously inadvisable for security reasons).