AppleScript: set Safari tab to specific index

If you are just trying to set the value of the tab index of item 1 of t to a variable, then is there some reason you can not just use set theTabNumber to index of item 1 of t instead of set theTabNumber to item 1 of t? -- This code, set theTabNumber to index of item 1 of t returns an integer, representing the r/o index of the tab, ordered left to right in that window.

That said, looking at the code in your OP, as coded, the do JavaScript ... command is going to execute regardless of the result of both search strings, which of course doesn't make any sense!

If you are testing for multiple search strings, it is more logical to execute different do JavaScript ... commands based on the results.

That said, as an exercise (hopefully not in futility) I decided to write a handler from scratch that does the following:

• Takes a search string.
• Searches the name of every tab of every window for the search string.
• If the search string is not found in the name, it searches the URL for it.
• If the search string is found, it brings the target tab and window to the front and returns a list with the tab index and window id.
• If the search string is not found, it returns a list with missing value for each item of the list, which can be used as the flag to execute a different search string.

For testing purposes, with multiple windows having multiple tabs with at least one set to "https://www.facebook.com" or "https://twitter.com" on different test runs of the example AppleScript code, and not logged into either, will search for "Facebook" or "Twitter" to bring their windows to the front and be the current tab to execute a do JavaScript ... command that will click the Create New Account button on Facebook or the Sign up button on Twitter.

Note: The code that brings the target window to the front and sets the target tab to the current tab can be commented out and use what's returned from the handler to target the tab by its index and the window by its id so it can be done in the background if wanted.

Example AppleScript code:

findTabContainingSearchString("Facebook")
if result does not contain missing value then
    tell application "Safari" to tell document 1 to do JavaScript ¬
        "document.getElementsByClassName('_42ft _4jy0 _6lti _4jy6 _4jy2 selected _51sy')[0].click();"
else
    findTabContainingSearchString("Twitter")
    if result does not contain missing value then
        tell application "Safari" to tell document 1 to do JavaScript ¬
            "document.getElementsByClassName('css-901oao r-1awozwy r-jwli3a r-6koalj r-18u37iz r-16y2uox r-1qd0xha r-a023e6 r-vw2c0b r-1777fci r-eljoum r-dnmrzs r-bcqeeo r-q4m81j r-qvutc0')[0].click();"
    end if
end if


on findTabContainingSearchString(searchString)
    tell application "Safari"
        set tabIndex to missing value
        set winID to missing value
        set winList to windows
        repeat with w in winList
            set tabList to (tabs of w whose name contains searchString)
            try
                set tabIndex to (get index of first item of tabList)
            end try
            if tabIndex is not missing value then
                set winID to id of w
                exit repeat
            else
                set tabList to (tabs of w whose URL contains searchString)
                try
                    set tabIndex to (get index of first item of tabList)
                end try
                if tabIndex is not missing value then
                    set winID to id of w
                    exit repeat
                end if
            end if
        end repeat
        if winID is not missing value then
            set current tab of window id winID to tab tabIndex of window id winID
            set index of window id winID to 1
        end if
        return tabIndex & winID
    end tell
end findTabContainingSearchString

Alternate Methods

If you have commented out the if winID is not missing value then block in the handler in order to execute the do JavaScript ... command in the background, change:

tell application "Safari" to tell document 1 to do JavaScript ¬

To:

set {tabIndex, winID} to result
tell application "Safari" to tell tab tabIndex of window id winID to do JavaScript ¬

Or use an even different approach:

set {tabIndex, winID} to findTabContainingSearchString("Facebook")
if {tabIndex, winID} does not contain missing value then
tell application "Safari" to tell tab tabIndex of window id winID to do JavaScript ¬