AppleScript checking if folder exists causes “AppleEvent handler failed” error -10000

applescript

AppleScript on macOS Mojave and can't work out why this script gives the expected "TRUE" on the first folder, but instead of "FALSE" on the second folder it aborts with the error message:

[error "Finder got an error: AppleEvent handler failed." number -10000 from folder (file "Felix HD:Users:Billy:TESTING:FOLDER2"]

tell application "Finder"

    set targetFolder to POSIX file "/Users/Billy/TESTING/FOLDER1" -- Existing folder

    if exists folder targetFolder then
        say "TRUE"
    else
        say "FALSE"
    end if

    set targetFolder to POSIX file "/Users/Billy/TESTING/FOLDER2" -- Non-existing folder

    if exists folder targetFolder then
        say "TRUE"
    else
        say "FALSE"
    end if

end tell

Best Answer

I think I found the answer: removed the word 'folder' from the if statements and now it works!

If anyone could confirm this is the proper syntax that would be great.

tell application "Finder"

    set targetFolder to POSIX file "/Users/Billy/TESTING/FOLDER1" -- Existing folder

    if exists targetFolder then
        say "TRUE" -- result!!
    else
        say "FALSE"
    end if

    set targetFolder to POSIX file "/Users/Billy/TESTING/FOLDER2" -- Non-existing folder

    if exists targetFolder then
        say "TRUE"
    else
        say "FALSE" -- result!!
    end if

end tell

Related Solutions

Why is the applescript for checking if a file exists failing

It looks like the Finder needs the absolute path to the home folder instead of the relative path. Instead of starting the path with ~/, it needs to start with /Users/username/.

Instead of hardcoding the username into the script, you can have AppleScript build the absolute path on the fly:

set homePath to POSIX path of (path to home folder)

Then you can replace "~/ with homePath & "

For example:

if exists "~/Downloads/Conversion/" & cbUsername & ".flv" as POSIX file then

would become

if exists homePath & "Downloads/Conversion/" & cbUsername & ".flv" as POSIX file then

Alternatively, if you only use ~ with the path ~/Downloads/Conversion/, you could instead change that whole path to a variable:

set cbPath to POSIX path of (path to home folder) & "Downloads/Conversion/"

Then the final script would be:

set cbPath to POSIX path of (path to home folder) & "Downloads/Conversion/"

tell application "Finder"
    if exists cbPath & cbUsername & ".flv" as POSIX file then
        set x to 1
        repeat
            set newCbFilename to cbUsername & "_" & x as string
            if exists cbPath & newCbFilename & ".flv" as POSIX file then
                set x to x + 1
            else
                exit repeat
            end if
        end repeat
        copy newCbFilename to finalCbFilename
        display dialog "Filename already exists " & "File will be named: " & finalCbFilename & ".flv" buttons "OK" default button "OK" with title "Error" with icon caution
    else
        copy cbUsername to finalCbFilename
    end if
end tell

Applescript giving error 1728 when checking if file exists

Try:

set dest_folder to POSIX path of dest_folder
set newFilepathPOSIX to dest_folder & "video.mp4"

tell application "System Events" to exists file newFilepathPOSIX
if the result then
    display dialog "There is already a file named \"video.mp4\". Do you want to replace the file?" buttons {"Quit", "No", "Yes"} cancel button 1
    if button returned of the result = "No" then
        beep
        --Insert your code here
    end if
end if

EDIT

 set handPath to "/Volumes/Flash Drive/HandBrakeCLI"
set dest_folder to POSIX path of dest_folder
if text -1 of dest_folder ≠ "/" then set dest_folder to dest_folder & "/"
set newFilepathPOSIX to dest_folder & "video.mp4"

tell application "System Events" to exists newFilepathPOSIX
if the result then
    display dialog "There is already a file named \"video.mp4\". Do you want to replace the file?" buttons {"Quit", "No", "Yes"} cancel button 1
    if button returned of the result = "No" then set newFilepathPOSIX to dest_folder & "video" & getDateAsString(current date) & ".mp4"
end if

set shellCommand to quoted form of handPath & " -i " & quoted form of origFilepathPOSIX & " -o " & quoted form of newFilepathPOSIX & " --preset=\"Classic\""
do shell script shellCommand

on getDateAsString(myDate)
    set creationDateString to year of myDate as string
    set creationDateString to creationDateString & text -2 thru -1 of ("0" & (month of myDate as integer) as text)
    set creationDateString to creationDateString & text -2 thru -1 of ("0" & day of myDate as text)
    set creationDateString to creationDateString & text -2 thru -1 of ("0" & hours of myDate as text)
    set creationDateString to creationDateString & text -2 thru -1 of ("0" & minutes of myDate as text)
    set creationDateString to creationDateString & text -2 thru -1 of ("0" & seconds of myDate as text)
end getDateAsString

Best Answer

Related Solutions

Why is the applescript for checking if a file exists failing

Applescript giving error 1728 when checking if file exists

Related Question