Always open the finder in new tab

finder

I want a folder to be always opened in a tab instead of new window. The reason I want this is so that I have only one Finder window with multiple tabs.
If apps keeps on opening new window you may miss the opened folder.
New to mac so wondering how to do.

I am using OS X 10.9.2

Best Answer

As noted by another answer: you can't have all new Finder calls open as tabs in one Finder window. Cool idea though.

And, as noted by another answer: you can control the behaviour of Cmd-Click actions in Finder so they open new tabs instead of new windows by going to the Finder preferences (Cmd+) and making sureOpen folders in tabs instead of new windows` is selected in the General tab on the Preferences pane:

Finder preferences for tabs instead of windows

The reason I want this is so that I have only one Finder window with multiple tabs. If apps keeps on opening new window you may miss the opened folder.

The above preference settings for Finder won't stop apps from opening new windows. You can, however, use Finder's Window > Merge All Windows menu item to pull all open Finder windows in to the current, front-most, Finder window as tabs. This will address your straggler concerns, though in an inelegant manner I'm afraid.

You could use this Alfred workflow to trigger the Merge from Alfred. Or, if you're a LaunchBar user like me, here's a little AppleScript that'll do it:

on gui_scripting_status()
  tell application "System Events"
    set ui_enabled to UI elements enabled
  end tell
  if ui_enabled is false then
    tell application "System Preferences"
      activate
      set current pane to pane id "com.apple.preference.universalaccess"
      display dialog "The GUI scripting architecture of Mac OS X is currently disabled." & return & return & "To activate GUI Scripting select the checkbox \"Enable access for assistive devices\" in the Universal Access preference pane." with icon 1 buttons {"Okay"} default button 1
    end tell
  end if
  return ui_enabled
end gui_scripting_status

on click_menu(app_name, menu_name, menu_item)
  try
    tell application app_name
      activate
    end tell
    tell application "System Events"
      click menu item menu_item of menu menu_name of menu bar 1 of process app_name
    end tell
    return true
  on error error_message
    return false
  end try
end click_menu

if gui_scripting_status() then
  click_menu("Finder", "Window", "Merge All Windows")
end if

It's based off of this handy code blob. It'll work for other programs too like Safari. You need to enable access for assistive devices on your Mac for that script to work.

Related Question